terça-feira, 28 de junho de 2011

Ex.08 - Números pares e ímpares de um vetor

Escreva um algoritmo que leia e mostre um vetor de 20 elementos inteiros. a seguir, conte quantos
valores pares e ímpares existem no vetor.

Entendendo...

Vamos criar um vetor com 20 posições e ler cada uma delas, e depois mostrar na tela, sem novidades =)

Teremos uma condição onde validaresmo os números pares e impares, pegaremos o resto da divisão do número lido, se for = zero será par senao impar.

Muito Semelhante ao Ex. 05.

Uma possível solução:

algoritmo "Ex.08 - Números pares e ímpares de um vetor"

// Autor :Eduardo V. de Souza
// Data : 28/06/2011

var

//Declaração das variáveis
vet:vetor[1..20] de inteiro
i,cont_par,cont_imp:inteiro

inicio

//inicializando os contadores
cont_imp<-0
cont_par<-0

escreval("Digite todos os números")

para i de 1 ate 20 faca
//lendo cada elemento do vetor
leia(vet[i])
//aqui todo o calculo, se nao existir resto na divisao = par
//senao impar
se (vet[i]%2) = 0 entao
//se par, o contador recebe seu valor + 1
cont_par<-cont_par+1
senao
//se par, o contador recebe seu valor + 1
cont_imp<-cont_imp+1
fimse
fimpara

// eu sei que bagunça mas estou mostrando na tela todos os lidos
para i de 1 ate 20 faca
escreval("Elemento nº ",i," do vetor = ",vet[i])
fimpara

// e finalmente mostrando o resultado
escreval("O total de números pares lidos foi ",cont_par)
escreval("O total de números ímpares lidos foi ",cont_imp)

fimalgoritmo

Em execução:



segunda-feira, 27 de junho de 2011

Ex. 07 - Multiplicação entre Vetores

Escreva um algoritmo que leia dois vetores de 5 posições e faça a multiplicação dos elementos de mesmo índice, colocando o resultado em um terceiro vetor. Mostre o vetor resultante.

Entendendo...

Vamos criar 3 vetores, cada um com 5 posições, dois deles vamos preencher com valores inteiros.
O terceiro sera preenchido com a multiplicação dos outros dois. Como?

vetor1 x vetor2? Sim isso mesmo!

vetor1 na posição(1) x vetor2 na posição(1) preencherá o valor do vetor3 na posição(1) e assim por diante.

Uma possível solução:

algoritmo "Multiplicação entre vetores"

// Autor : Eduardo V. de Souza
// Data : 27/06/2011

var vet_1:vetor[1..5]de inteiro
vet_2:vetor[1..5]de inteiro
vet_3:vetor[1..5]de inteiro
i:inteiro

inicio

aleatorio 1,10 // ativa opção aleatoria do visualg


// nesse bloco criamos e preenchemos com valores
//randomicos o primeiro vetor
para i de 1 ate 5 faca
escreval("Preenchendo o ",i, "º campo do primeiro vetor")
leia(vet_1[i])
fimpara
// nesse bloco criamos e preenchemos com valores
//randomicos o segundo vetor
para i de 1 ate 5 faca
escreval("Preenchendo o ",i, "º campo do segundo vetor")
leia(vet_2[i])
fimpara

// nesse ultimo eu preencho o terceiro vetor com
//a multiplicação do 1º com o 2º e logo em seguida
//efetuo a leitura do mesmo mostrando na tela o resultado

para i de 1 ate 5 faca
escreval("mult do 1º com o 2º na pos",i, "º campo do 3º vetor")
//preenchendo o terceiro vetor
vet_3[i]<- vet_1[i] * vet_2[i]
escreval(vet_3[i])
fimpara
fimalgoritmo

Em execução:

sábado, 25 de junho de 2011

Ex. 06 - Fatorial

Dado um número, calcule seu fatorial.

Entendendo:

Teremos que ler um número e encontrar seu fatorial, faremos isso entendendo um pouco mais sobre fatorial, ou seja a soma da multiplicação de um número (n) vezes, onde n é o número lido.

Uma possível Solução:

algoritmo "Fatorial"

//Autor: Eduardo V. Souza
// Data : 25/06/2011

var

fat,x,i:inteiro
// declarando as variáveis.
// aqui temos 3 variaveis, uma para o indice do laço
//outra para leitura do número e uma para calcular o fat.
inicio

escreval("Digite um número")
leia(x)

// como vamos multiplicar precisamos inciar o valor de fat com 1
fat<-1

// nesse bloco é calculado o fatorial
//para i que incia de 2 até o núemro lido (x)
para i de 2 ate x faca

//fat que tem o valor de 1 recebe a soma dele mesmo multiplicado
// por i que começa em 2 dentro do laço de repetição
fat<-fat*i
fimpara
//escreve o fatorial
escreval("fatorial =",fat)

fimalgoritmo

Em Execução:

sexta-feira, 24 de junho de 2011

Ex. 05 - Número é par ou ímpar, e se é positivo ou negativo

Faça um algoritmo que leia um nº inteiro e mostre uma mensagem indicando se este número é par ou ímpar, e se é positivo ou negativo.

Entendendo...

Aqui teremos que ler um número e verificar se ele e maior ou menor que zero, e depois verificar se ele e par ou impar, verificaremos se ele e par ou impar pegando o resto da divisão por 2 (mod), se o resultado for zero então ele é par, senao é impar.

Uma possível Solução:

algoritmo "Número é par ou ímpar, e se é positivo ou negativo"

// Autor : Eduardo V. de Souza
// Data : 24/06/2011

var

num: inteiro

inicio

escreval("Digite o número")
leia(num)//Lendo a variável


//verificando o resto da divisão por 2, se = 0 par senao impar
se (num % 2) = 0 entao
escreval("O número é par")
senao
escreval("O número é impar")
fimse

//verificando se é maior ou = 0
// vou considerar aqui zero como numero positivo
se (num >= 0) entao
escreval("O número é positivo")
senao
escreval("O número é negativo")
fimse

fimalgoritmo

Em execução: